%{
/*{{定型コード:y.tab.y(宣言部,%{〜%}内)======================================*/
#ifdef  PIECE
#include "app.h"
#else //PIECE
#include "winapp.h"
#endif//PIECE
/* パーサースタックの初期値を定義します。
 * sizeof(YYSTYPE)*YYINITDEPTH) がスタック上に確保されます。
 * デフォルトでは200と定義されており、P/ECEには大きすぎます。
 * P/ECEに適切な、小さなサイズ(16)に、再定義しました。
 * パーサースタックが不足した場合は、自動的に拡張されるので、問題ありません。
 */
#define YYINITDEPTH 16
///* エラー報告関数を定義します。 */	→{{2015/03/06:'-e'オプション対応のためにwinapp.cへ移動しました。}}
//void yyerror(const char* fmt, ...) {
//  fprintf(stderr, "### error at line %d : ", yylineno);
//  { va_list ap; va_start(ap, fmt); vfprintf(stderr, fmt, ap); va_end(ap); }
//  fputc('\n', stderr); }
/*}}定型コード:y.tab.y(宣言部,%{〜%}内)======================================*/
%}

%union {
	int   v_num;
	char* v_lab;
}
%token T_DEF
%token T_END
%token T_REPEAT
%token T_WAIT
%token T_CALL
%token T_ACT
%token T_FLUSH
%token T_ON
%token T_GOTO
%token T_LOCK
%token T_UNLOCK
%token T_SET
%token T_CLR
%token <v_num> T_NUM
%token <v_lab> T_LAB
%token T_EOL

%left '|'
%left '^'
%left '&'
%left '<' '>'
%left '+' '-'
%left '*' '/'
%nonassoc T_UPL T_UMI
%type <v_num> expr
%type <v_num> trig

%%

all
	: /* empty */
	| all line
	;
line
	:       T_EOL
	| inst  T_EOL
	| error T_EOL					{ yyerrok; }		//全てのシンタクスエラーを報告するために継続する。
	;
inst
	: T_DEF T_LAB					{ inst_def($2); }
	|       T_LAB					{ inst_def($1); }	//省略記法
	//
	| T_END						{ inst_end(); }
	//
	| T_REPEAT expr					{ inst_repeat($2); }
	| T_REPEAT					{ inst_repeat(255); }	//無限
	//
	| T_WAIT expr					{ inst_wait($2); }
	//
	| T_CALL T_LAB					{ inst_call($2); }
	//
	| T_ACT expr					{ inst_act(0, $2); }
	| T_ACT expr T_FLUSH				{ inst_act(1, $2); }
	//
	| T_ON trig          goto T_LAB			{ inst_on(0, $2, $4,  0); }
	| T_ON trig          goto T_LAB lock expr	{ inst_on(0, $2, $4, $6); }
	| T_ON trig T_UNLOCK goto T_LAB			{ inst_on(1, $2, $5,  0); }
	| T_ON trig T_UNLOCK goto T_LAB lock expr	{ inst_on(1, $2, $5, $7); }
	;
goto
	: /* empty */
	| T_GOTO
	;
lock
	: /* empty */
	| T_LOCK
	;
trig
	: expr
	| T_SET			{ $$ =   0; }
	| T_CLR			{ $$ = 255; }
	;
expr
	: T_NUM
	| '(' expr ')'		{ $$ =  $2; }
	| '+' expr %prec T_UPL	{ $$ =  $2; }
	| '-' expr %prec T_UMI	{ $$ = -$2; }
	| expr '+' expr		{ $$ = $1 + $3; }
	| expr '-' expr		{ $$ = $1 - $3; }
	| expr '*' expr		{ $$ = $1 * $3; }
	| expr '/' expr		{ $$ = $1 / $3; }
	| expr '&' expr		{ $$ = $1 & $3; }
	| expr '^' expr		{ $$ = $1 ^ $3; }
	| expr '|' expr		{ $$ = $1 | $3; }
	| expr '<' expr		{ $$ = $1 << $3; }
	| expr '>' expr		{ $$ = $1 >> $3; }
	;

%%
