@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0

REM ProdDefNo.hとProdDefNo.cが既に有れば、確実に削除しておきます。
IF EXIST ProdDefNo.h DEL ProdDefNo.h
IF EXIST ProdDefNo.c DEL ProdDefNo.c

REM ■説明
REM 
REM □sort.exe ProdDef.h ^
REM ProdDef.hをソートします。
REM 名前が連続した演出セットに連番を振ると、プログラムで扱い易いからです。
REM 
REM □ | gawk.exe --re-interval -f %BATDIR%MkProdDefNo.awk ^
REM ProdDef.h(演出セットインデクスの定義)を、インデクステーブルに変換するAwkスクリプトです。
REM 詳細は、MkProdDefNo.awkのコメントを参照してください。
REM 
REM □  | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w ProdDef.h" ^
REM                    -e "/{{SOURCE/,/}}SOURCE/w ProdDef.c"
REM ヘッダ部とソース部に切り分けて保存します。

sort.exe ProdDef.h ^
 | gawk.exe --re-interval -f %BATDIR%MkProdDefNo.awk ^
 | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w ProdDefNo.h" ^
                -e "/{{SOURCE/,/}}SOURCE/w ProdDefNo.c"

REM ProdDefNo.hとProdDefNo.cの作成途中でエラー中断した場合は、ファイルを削除して、バッチスクリプトをエラー終了します。
IF EXIST ProdDefNo.h ( grep.exe -q "}}HEADER" ProdDefNo.h || DEL ProdDefNo.h )
IF EXIST ProdDefNo.c ( grep.exe -q "}}SOURCE" ProdDefNo.c || DEL ProdDefNo.c )
IF NOT EXIST ProdDefNo.h EXIT /B 1
IF NOT EXIST ProdDefNo.c EXIT /B 1
