%{
/*{{定型コード:y.tab.y(宣言部,%{〜%}内)======================================*/
#ifdef  PIECE
#include "app.h"
#else //PIECE
#include "winapp.h"
#pragma warning(default: 4131)	//{{2016/03/01追加:clipstd.hにてC4131の警告レベルを引き上げましたが、Bison/Flexの生成コードには旧スタイルの宣言が使われているので、Bison/Flexの生成コードのみ警告レベルを元に戻しました。}}
#endif//PIECE
/* パーサースタックの初期値を定義します。
 * sizeof(YYSTYPE)*YYINITDEPTH) がスタック上に確保されます。
 * デフォルトでは200と定義されており、P/ECEには大きすぎます。
 * P/ECEに適切な、小さなサイズ(16)に、再定義しました。
 * パーサースタックが不足した場合は、自動的に拡張されるので、問題ありません。
 */
#define YYINITDEPTH 16
///* エラー報告関数を定義します。 */	→{{2015/03/06:'-e'オプション対応のためにwinapp.cへ移動しました。}}
//void yyerror(const char* fmt, ...) {
//  fprintf(stderr, "### error at line %d : ", yylineno);
//  { va_list ap; va_start(ap, fmt); vfprintf(stderr, fmt, ap); va_end(ap); }
//  fputc('\n', stderr); }
/*}}定型コード:y.tab.y(宣言部,%{〜%}内)======================================*/
%}

%union {
	int		v_num;
	double		v_dbl;
	char*		v_str;
	ST_Anm*		v_anm;
	ST_KeyRow*	v_keyRow;
	ST_KeyRows*	v_keyRows;
//{{2018/04/11追加:「repeat N」を追加しました。
	ST_KeyRowsN*	v_keyRowsN;
//}}2018/04/11追加:「repeat N」を追加しました。
}

%token	<v_num>		T_NUM
%token	<v_dbl>		T_DBL
%token	<v_str>		T_LAB
%token			T_EOL
%token			T_REPEAT
%token			T_END
%token			T_LOOP
%token			T_STAY

%type	<v_num>		int_arg
%type	<v_num>		expr
%type	<v_dbl>		edbl
%type	<v_str>		labRow
%type	<v_anm>		anm
%type	<v_keyRow>	keyRow
%type	<v_keyRows>	keyRows
//{{2018/04/11追加:「repeat N」を追加しました。
%type	<v_num>		repeatN
%type	<v_keyRowsN>	keyRowsN
//}}2018/04/11追加:「repeat N」を追加しました。

%left			'|'
%left			'^'
%left			'&'
%left			T_SHL T_SHR
%left			'+' '-'
%left			'*' '/' '%'
%nonassoc		'~' T_UPL T_UMI T_CAST_INT T_CAST_DBL

%%

all
		: pre_blank
		| all anm					{ addAnm($2); yyerrok; }	//error記号の位置について『http://www.pwv.co.jp/~take/TakeWiki/index.php?Cコンパイラ設計(yacc・lexの応用)/第4章　エラー・リカバリ#dbd8d417』の【optional sequence】を参考にした。
		| all error									//全てのシンタクスエラーを報告するために継続する。
		;
pre_blank
		: /* empty */
		| pre_blank T_EOL
		;
eols
		:      T_EOL
		| eols T_EOL
		;
repeat
		: T_REPEAT         eols
		;
//{{2018/04/11追加:「repeat N」を追加しました。
repeatN
		: T_REPEAT int_arg eols				{ if($2 < 1) { yyerror("repeat count < 1"); yynerrs++; YYERROR; } $$ = $2; }
		;
//}}2018/04/11追加:「repeat N」を追加しました。
end
		: T_END            eols
		;
loop
		: T_LOOP           eols
		;
stay
		: T_STAY           eols
		;
int_arg
		: expr						/* use default action */
		| edbl						{ $$ =  cast_dbl_to_int($1); }
		;
expr
		: T_NUM						/* use default action */
		| '(' expr ')'					{ $$ =  $2; }
		| T_CAST_INT expr				{ $$ =  $2; }
		| T_CAST_INT edbl				{ $$ =  $2; }
		| '+' expr %prec T_UPL				{ $$ =  $2; }
		| '-' expr %prec T_UMI				{ $$ = -$2; }
		| '~' expr					{ $$ = ~$2; }
		| expr '+' expr					{ $$ = $1 + $3; }
		| expr '-' expr					{ $$ = $1 - $3; }
		| expr '*' expr					{ $$ = $1 * $3; }
		| expr '/' expr					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
		| expr '%' expr					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 % $3; }
		| expr '&' expr					{ $$ = $1 & $3; }
		| expr '^' expr					{ $$ = $1 ^ $3; }
		| expr '|' expr					{ $$ = $1 | $3; }
		| expr T_SHL expr				{ if((unsigned)$3 >= 32) { yyerror("shift count >= 32"); yynerrs++; YYERROR; } $$ = $1 << $3; }
		| expr T_SHR expr				{ if((unsigned)$3 >= 32) { yyerror("shift count >= 32"); yynerrs++; YYERROR; } $$ = $1 >> $3; }
		;
edbl
		: T_DBL
		| '(' edbl ')'					{ $$ =  $2; }
		| T_CAST_DBL expr				{ $$ =  $2; }
		| T_CAST_DBL edbl				{ $$ =  $2; }
		| '+' edbl %prec T_UPL				{ $$ =  $2; }
		| '-' edbl %prec T_UMI				{ $$ = -$2; }
		| edbl '+' edbl					{ $$ = $1 + $3; }
		| edbl '+' expr					{ $$ = $1 + $3; }
		| expr '+' edbl					{ $$ = $1 + $3; }
		| edbl '-' edbl					{ $$ = $1 - $3; }
		| edbl '-' expr					{ $$ = $1 - $3; }
		| expr '-' edbl					{ $$ = $1 - $3; }
		| edbl '*' edbl					{ $$ = $1 * $3; }
		| edbl '*' expr					{ $$ = $1 * $3; }
		| expr '*' edbl					{ $$ = $1 * $3; }
		| edbl '/' edbl					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
		| edbl '/' expr					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
		| expr '/' edbl					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
		;
		/*--------------------------------------------*/
anm
		: labRow keyRows                end		{ if(!($$ = Anm_New($1, $2, NULL, 0))) { YYERROR; } }	//─ループ無し
		| labRow keyRows repeat keyRows end		{ if(!($$ = Anm_New($1, $2,   $4, 0))) { YYERROR; } }	//─イントロ＋ループ
		| labRow         repeat keyRows end		{ if(!($$ = Anm_New($1, NULL, $3, 0))) { YYERROR; } }	//┬書式が違うだけで同じ意味です。どちらも全体ループになります。
		| labRow keyRows               loop		{ if(!($$ = Anm_New($1, NULL, $2, 0))) { YYERROR; } }	//┘
		| labRow keyRows               stay		{ if(!($$ = Anm_New($1, NULL, $2, 1))) { YYERROR; } }	//─最後のフレームでステイします。
		;
labRow
		: T_LAB eols					/* use default action */
		;
keyRows
		:         keyRow				{ if(!($$ = KeyRows_Add(NULL, $1))) { YYERROR; } }
		| keyRows keyRow				{ if(!($$ = KeyRows_Add(  $1, $2))) { YYERROR; } }
//{{2018/04/11追加:「repeat N」を追加しました。
		|         keyRowsN				{ if(!($$ = KeyRows_AddN(NULL, $1))) { YYERROR; } }
		| keyRows keyRowsN				{ if(!($$ = KeyRows_AddN(  $1, $2))) { YYERROR; } }
//}}2018/04/11追加:「repeat N」を追加しました。
		;
keyRow
		: int_arg             eols			{ if(!($$ = KeyRow_New($1,  1))) { YYERROR; } }		//省略記法
		| int_arg ',' int_arg eols			{ if(!($$ = KeyRow_New($1, $3))) { YYERROR; } }
		;
//{{2018/04/11追加:「repeat N」を追加しました。
keyRowsN
		: repeatN keyRows end				{ if(!($$ = KeyRowsN_New($1, $2))) { YYERROR; } }
		;
//}}2018/04/11追加:「repeat N」を追加しました。

%%
