@ECHO OFF
SET BATDIR=%~dp0
REM //{{2018/04/07変更:criatomencd.exeのパスを変更しました。
REM //SET CRIATOMENCD=C:\cri\tools\criatomex\criatomencd.exe
REM //↓2018/04/07変更:criatomencd.exeのパスを変更しました。
SET CRIATOMENCD=C:\cri\tools\ADX2\ver.2\criatomencd.exe
REM //}}2018/04/07変更:criatomencd.exeのパスを変更しました。

REM //--------------------------------------------------------------------------
REM // * Tue Aug 23 21:53:38 JST 2016 Naoyuki Sawa
REM // - 1st リリース。
REM //   カレントフォルダ以下に有る*.wavファイルを、全て*.hcaファイルに変換するバッチスクリプトの雛型です。
REM //   実際には、このバッチスクリプトそのままであらゆるケースに対応する事は出来ないと思うので、適宜コピーして変更して下さい。
REM // * Sat Apr 07 23:59:59 JST 2018 Naoyuki Sawa
REM // - ファイル名に空白を含むファイルも変換出来るようにしました。
REM //   これまでは、ファイル名に空白が含まれていると間違って分割してしまっており、正しく変換出来ていませんでした。
REM //   ファイル名に空白が含まれている可能性が有る場合は、'delims='の指定が必要でした。
REM //   □参照資料:「Programming Field」(https://www.pg-fl.jp/)さんの、『DOS コマンド一覧 - For』(https://www.pg-fl.jp/program/dos/doscmd/for.htm)の記事より引用:
REM //   │delimitersを記述しない空の「delims=」指定と、「delims」指定そのものを省略した構文とでは、区切り文字に関する意味が異なります。
REM //   │区切り文字で分割せずに行全体を変数に与えたい場合は、明示的に「delims=」と指定を入れる必要があります(さらにスペースが区切り文字として扱われないように、必ず最後の指定にする必要があります)。
REM // - criatomencd.exeのパスを変更しました。
REM //   昨年の夏頃迄は「C:\cri\tools\criatomex\criatomencd.exe」に有ったのですが、いつの間にか「C:\cri\tools\ADX2\ver.2\criatomencd.exe」に変わっていたようです。
REM //   今見ると「C:\cri\tools\criatomex\」というフォルダ自体が無くなっているので、フォルダ構成が変わったのだと思います。

REM //--------------------------------------------------------------------------
COLOR C
ECHO ★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★
ECHO │このバッチスクリプトは、カレントフォルダ以下の、*.hcaファイルを、全て削除します。               │
ECHO │間違ったフォルダで実行すると非常に危険なので、パスが通ったフォルダには置かないようにして下さい。│
ECHO │プロジェクトの素材フォルダ内に、このバッチスクリプトをコピーして、直接実行するようにして下さい。│
ECHO ★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★
ECHO.
ECHO 本当に実行するならば、三秒後に、何かキーを押して下さい。
ECHO やっぱりやめるならば、コマンドプロンプトを閉じて下さい。
ECHO.
TIMEOUT /T 3 /NOBREAK
COLOR 7
PAUSE

REM //--------------------------------------------------------------------------
REM //カレントフォルダ以下に有る、*.hcaファイルを、全て削除する。
DEL /S *.hca

REM //--------------------------------------------------------------------------
REM //カレントフォルダ以下に有る、*.wavファイルを、全て変換する。
REM //{{2018/04/07変更:ファイル名に空白を含むファイルも変換出来るようにしました。
REM //FOR /F "usebackq" %%i IN (`DIR /B /S *.wav`) DO (
REM //↓2018/04/07変更:ファイル名に空白を含むファイルも変換出来るようにしました。
FOR /F "usebackq delims=" %%i IN (`DIR /B /S *.wav`) DO (
REM //}}2018/04/07変更:ファイル名に空白を含むファイルも変換出来るようにしました。
  %CRIATOMENCD% "%%i" ^
                "%%~dpni.hca"
  IF ERRORLEVEL 1 GOTO L_ERR
)

REM //--------------------------------------------------------------------------
ECHO 完了しました。
	TIMEOUT /T 3 /NOBREAK
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
ECHO ###エラーが発生しました。
	PAUSE
EXIT /B 1
