@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Fri May 11 23:59:59 JST 2018 Naoyuki Sawa
REM // - 1st リリース。MkVslDef.batをベースにしました。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkMesDef.bat メッシュ定義スクリプト [[メッシュ定義スクリプト] ...]
REM //│(メッシュ定義スクリプトの書式は、dMesDefC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、メッシュ定義スクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dMesDefC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「メッシュ定義コンパイラ」を実行します。
dMesDefC.exe -e -uEnmMesDef.tmp -rRegMesDef.tmp %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR
DEL %TMPNAM%

REM //--------------------------------------------------------------------------
REM //□列挙定義スクリプトに、タブ文字を追加して列幅を揃えます。
TabAlign.exe EnmMesDef.tmp > EnmMesDef.txt
IF ERRORLEVEL 1 GOTO L_ERR
DEL EnmMesDef.tmp

REM //--------------------------------------------------------------------------
REM //□レジストリスクリプトに、タブ文字を追加して列幅を揃えます。
TabAlign.exe RegMesDef.tmp > RegMesDef.txt
IF ERRORLEVEL 1 GOTO L_ERR
DEL RegMesDef.tmp

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST EnmMesDef.txt DEL EnmMesDef.txt
IF EXIST RegMesDef.txt DEL RegMesDef.txt
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
