%{
/*{{定型コード:y.tab.y(宣言部,%{〜%}内)======================================*/
#ifdef  PIECE
#include "app.h"
#else //PIECE
#include "winapp.h"
#pragma warning(default: 4131)	//{{2016/03/01追加:clipstd.hにてC4131の警告レベルを引き上げましたが、Bison/Flexの生成コードには旧スタイルの宣言が使われているので、Bison/Flexの生成コードのみ警告レベルを元に戻しました。}}
#endif//PIECE
/* パーサースタックの初期値を定義します。
 * sizeof(YYSTYPE)*YYINITDEPTH) がスタック上に確保されます。
 * デフォルトでは200と定義されており、P/ECEには大きすぎます。
 * P/ECEに適切な、小さなサイズ(16)に、再定義しました。
 * パーサースタックが不足した場合は、自動的に拡張されるので、問題ありません。
 */
#define YYINITDEPTH 16
///* エラー報告関数を定義します。 */	→{{2015/03/06:'-e'オプション対応のためにwinapp.cへ移動しました。}}
//void yyerror(const char* fmt, ...) {
//  fprintf(stderr, "### error at line %d : ", yylineno);
//  { va_list ap; va_start(ap, fmt); vfprintf(stderr, fmt, ap); va_end(ap); }
//  fputc('\n', stderr); }
/*}}定型コード:y.tab.y(宣言部,%{〜%}内)======================================*/
%}

%union {
	int		v_num;
	double		v_dbl;
	char*		v_lab;
}

%token			T_DEF
%token			T_END
%token			T_WAIT
%token			T_STOP
%token			T_PLAY
%token			T_VOL
%token			T_PAN
%token	<v_num>		T_NUM
%token	<v_dbl>		T_DBL
%token	<v_lab>		T_LAB
%token			T_EOL

%type	<v_num>		int_arg
%type	<v_num>		expr
%type	<v_dbl>		edbl

%left			'|'
%left			'^'
%left			'&'
%left			T_SHL T_SHR
%left			'+' '-'
%left			'*' '/' '%'
%nonassoc		'~' T_UPL T_UMI T_CAST_INT T_CAST_DBL

%%

all
	: /* empty */
	| all line
	;
line
	:       T_EOL
	| inst  T_EOL
	| error T_EOL						{ yyerrok; }		/* 全てのシンタクスエラーを報告するために継続する */
	;
inst
	: T_DEF T_LAB						{ inst_def($2); }
	|       T_LAB						{ inst_def($1); }	/* 省略記法 */
	//
	| T_END							{ inst_end(); }
	//
	| T_WAIT int_arg					{ inst_wait($2); }
	//
	| T_STOP int_arg					{ inst_stop($2); }
	//
	| T_PLAY int_arg ',' int_arg ',' int_arg ',' int_arg ',' int_arg	{ inst_play_m($2, $4, $6, $8, $10); }
	| T_PLAY int_arg ',' int_arg ',' int_arg ',' int_arg			{ inst_play_s($2, $4, $6, $8); }
	//
	| T_VOL int_arg ',' int_arg				{ inst_vol($2, $4); }
	//
	| T_PAN int_arg ',' int_arg				{ inst_pan($2, $4); }
	;
int_arg
	: expr							/* use default action */
	| edbl							{ $$ =  cast_dbl_to_int($1); }
	;
expr
	: T_NUM
	| '(' expr ')'						{ $$ =  $2; }
	| T_CAST_INT expr					{ $$ =  $2; }
	| T_CAST_INT edbl					{ $$ =  $2; }
	| '+' expr %prec T_UPL					{ $$ =  $2; }
	| '-' expr %prec T_UMI					{ $$ = -$2; }
	| '~' expr						{ $$ = ~$2; }
	| expr '+' expr						{ $$ = $1 + $3; }
	| expr '-' expr						{ $$ = $1 - $3; }
	| expr '*' expr						{ $$ = $1 * $3; }
	| expr '/' expr						{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
	| expr '%' expr						{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 % $3; }
	| expr '&' expr						{ $$ = $1 & $3; }
	| expr '^' expr						{ $$ = $1 ^ $3; }
	| expr '|' expr						{ $$ = $1 | $3; }
	| expr T_SHL expr					{ if((unsigned)$3 >= 32) { yyerror("shift count >= 32"); yynerrs++; YYERROR; } $$ = $1 << $3; }
	| expr T_SHR expr					{ if((unsigned)$3 >= 32) { yyerror("shift count >= 32"); yynerrs++; YYERROR; } $$ = $1 >> $3; }
	;
edbl
	: T_DBL
	| '(' edbl ')'						{ $$ =  $2; }
	| T_CAST_DBL expr					{ $$ =  $2; }
	| T_CAST_DBL edbl					{ $$ =  $2; }
	| '+' edbl %prec T_UPL					{ $$ =  $2; }
	| '-' edbl %prec T_UMI					{ $$ = -$2; }
	| edbl '+' edbl						{ $$ = $1 + $3; }
	| edbl '+' expr						{ $$ = $1 + $3; }
	| expr '+' edbl						{ $$ = $1 + $3; }
	| edbl '-' edbl						{ $$ = $1 - $3; }
	| edbl '-' expr						{ $$ = $1 - $3; }
	| expr '-' edbl						{ $$ = $1 - $3; }
	| edbl '*' edbl						{ $$ = $1 * $3; }
	| edbl '*' expr						{ $$ = $1 * $3; }
	| expr '*' edbl						{ $$ = $1 * $3; }
	| edbl '/' edbl						{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
	| edbl '/' expr						{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
	| expr '/' edbl						{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
	;

%%
