@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0

REM RudDefNo.hとRudDefNo.cが既に有れば、確実に削除しておきます。
IF EXIST RudDefNo.h DEL RudDefNo.h
IF EXIST RudDefNo.c DEL RudDefNo.c

REM ■説明
REM 
REM □sort.exe RudDef.h ^
REM RudDef.hをソートします。
REM 名前が連続したシンボルに連番を振ると、プログラムで扱い易いからです。
REM 
REM □ | gawk.exe --re-interval -f %BATDIR%MkRudDefNo.awk ^
REM RudDef.h(台形制御シーケンサのインデクス定義)を、インデクステーブルに変換するAwkスクリプトです。
REM 詳細は、MkRudDefNo.awkのコメントを参照してください。
REM 
REM □  | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w RudDef.h" ^
REM                      -e "/{{SOURCE/,/}}SOURCE/w RudDef.c"
REM ヘッダ部とソース部に切り分けて保存します。

sort.exe RudDef.h ^
 | gawk.exe --re-interval -f %BATDIR%MkRudDefNo.awk ^
 | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w RudDefNo.h" ^
                  -e "/{{SOURCE/,/}}SOURCE/w RudDefNo.c"

REM RudDefNo.hとRudDefNo.cの作成途中でエラー中断した場合は、ファイルを削除して、バッチスクリプトをエラー終了します。
IF EXIST RudDefNo.h ( grep.exe -q "}}HEADER" RudDefNo.h || DEL RudDefNo.h )
IF EXIST RudDefNo.c ( grep.exe -q "}}SOURCE" RudDefNo.c || DEL RudDefNo.c )
IF NOT EXIST RudDefNo.h EXIT /B 1
IF NOT EXIST RudDefNo.c EXIT /B 1
