@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0

REM SndDefNo.hとSndDefNo.cが既に有れば、確実に削除しておきます。
IF EXIST SndDefNo.h DEL SndDefNo.h
IF EXIST SndDefNo.c DEL SndDefNo.c

REM ■説明
REM 
REM □sort.exe SndDef.h ^
REM SndDef.hをソートします。
REM 名前が連続したシンボルに連番を振ると、プログラムで扱い易いからです。
REM 
REM □ | gawk.exe --re-interval -f %BATDIR%MkSndDefNo.awk ^
REM SndDef.h(サウンドシーケンサのインデクス定義)を、インデクステーブルに変換するAwkスクリプトです。
REM 詳細は、MkSndDefNo.awkのコメントを参照してください。
REM 
REM □  | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w SndDef.h" ^
REM                      -e "/{{SOURCE/,/}}SOURCE/w SndDef.c"
REM ヘッダ部とソース部に切り分けて保存します。

sort.exe SndDef.h ^
 | gawk.exe --re-interval -f %BATDIR%MkSndDefNo.awk ^
 | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w SndDefNo.h" ^
                  -e "/{{SOURCE/,/}}SOURCE/w SndDefNo.c"

REM SndDefNo.hとSndDefNo.cの作成途中でエラー中断した場合は、ファイルを削除して、バッチスクリプトをエラー終了します。
IF EXIST SndDefNo.h ( grep.exe -q "}}HEADER" SndDefNo.h || DEL SndDefNo.h )
IF EXIST SndDefNo.c ( grep.exe -q "}}SOURCE" SndDefNo.c || DEL SndDefNo.c )
IF NOT EXIST SndDefNo.h EXIT /B 1
IF NOT EXIST SndDefNo.c EXIT /B 1
