@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Mon Mar 21 21:34:20 JST 2016 Naoyuki Sawa
REM // - 1st リリース。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkNcsSeq.bat NCS補間スクリプト [[NCS補間スクリプト] ...]
REM //│(NCS補間スクリプトの書式は、dNcsSeqC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、NCS補間スクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dNcsSeqC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「ステートレスNCS補間シーケンサコンパイラ」を実行します。
REM //環境変数'NCSSEQ_BIN'が定義されていなければ、テキスト形式で出力します。
IF "%NCSSEQ_BIN%" EQU "" (
  dNcsSeqC.exe -e                %TMPNAM% > NcsSeq.c
  IF ERRORLEVEL 1 GOTO L_ERR
  REM //NcsSeq.cから、ラベル定義の行を抽出して、NcsSeq.hを作成します。
  onigsed.exe -n -e "/^#define NcsSeqNo_/p" ^
                 -e "/^#define LedCh_Max/p" ^
                 -e "/^\(const int TBL_NcsSeqNo\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
                 -e "/^\(const int TBL_NcsSeq\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
   < NcsSeq.c > NcsSeq.h
  IF ERRORLEVEL 1 GOTO L_ERR
REM //環境変数'NCSSEQ_BIN'が定義されてたら、バイナリ形式で出力します。
) ELSE (
  dNcsSeqC.exe -e -o%NCSSEQ_BIN% %TMPNAM% > NcsSeq.h
  IF ERRORLEVEL 1 GOTO L_ERR
)
DEL %TMPNAM%

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST NcsSeq.h DEL NcsSeq.h
IF EXIST NcsSeq.c DEL NcsSeq.c
IF "%NCSSEQ_BIN%" NEQ "" IF EXIST "%NCSSEQ_BIN%" DEL "%NCSSEQ_BIN%"
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
