@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Thu Sep 24 21:14:20 JST 2015 Naoyuki Sawa
REM // - 1st リリース。MkFsmMap.batをベースにしました。
REM // * Sat Sep 26 20:18:20 JST 2015 Naoyuki Sawa
REM // - TabAlign.batを呼び出して、タブ文字を追加して列幅を揃える処理を追加しました。
REM //   これはレジストリスクリプトを読み易くするためだけであり、必須ではありません。
REM // * Tue Oct 20 21:27:55 JST 2015 Naoyuki Sawa
REM // - TabAlign.batをTabAlign.exeに置き換えた事に伴い、当バッチも変更しました。
REM //   動作結果には変更有りません。
REM // * Mon Dec 21 21:46:29 JST 2015 Naoyuki Sawa
REM // - エラーが発生した時に、不完全な最終出力ファイルを確実に削除するようにしました。
REM // * Sat Jan 23 21:37:38 JST 2016 Naoyuki Sawa
REM // - パイプライン実行に、pipefail.exeを使用するように変更しました。
REM //   処理内容には、変更は有りません。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkPrpTbl.bat プロパティテーブルスクリプト [[プロパティテーブルスクリプト] ...]
REM //│(プロパティテーブルスクリプトの書式は、dPrpTblC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、プロパティテーブルスクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dPrpTblC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「プロパティテーブルコンパイラ」を実行します。
dPrpTblC.exe -e -rRegPrpTbl.tmp %TMPNAM% > PrpTbl.h
IF ERRORLEVEL 1 GOTO L_ERR
DEL %TMPNAM%

REM //--------------------------------------------------------------------------
REM //□タブ文字を追加して列幅を揃えます。
TabAlign.exe RegPrpTbl.tmp > RegPrpTbl.txt
IF ERRORLEVEL 1 GOTO L_ERR
DEL RegPrpTbl.tmp

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST    PrpTbl.h   DEL    PrpTbl.h
IF EXIST RegPrpTbl.txt DEL RegPrpTbl.txt
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
