@ECHO OFF
SET BATDIR=%~dp0
SET FFMPEG2THEORA=ffmpeg2theora.exe

REM //--------------------------------------------------------------------------
REM // * Tue Aug 23 21:53:38 JST 2016 Naoyuki Sawa
REM // - 1st リリース。
REM //   カレントフォルダ以下に有る*.aviファイルを、全て*.ogvファイルに変換するバッチスクリプトの雛型です。
REM //   実際には、このバッチスクリプトそのままであらゆるケースに対応する事は出来ないと思うので、適宜コピーして変更して下さい。

REM //--------------------------------------------------------------------------
COLOR C
ECHO ★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★
ECHO │このバッチスクリプトは、カレントフォルダ以下の、*.ogvファイルを、全て削除します。               │
ECHO │間違ったフォルダで実行すると非常に危険なので、パスが通ったフォルダには置かないようにして下さい。│
ECHO │プロジェクトの素材フォルダ内に、このバッチスクリプトをコピーして、直接実行するようにして下さい。│
ECHO ★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★危険☆☆危険★★
ECHO.
ECHO 本当に実行するならば、三秒後に、何かキーを押して下さい。
ECHO やっぱりやめるならば、コマンドプロンプトを閉じて下さい。
ECHO.
TIMEOUT /T 3 /NOBREAK
COLOR 7
PAUSE

REM //--------------------------------------------------------------------------
REM //カレントフォルダ以下に有る、*.ogvファイルを、全て削除する。
DEL /S *.ogv

REM //--------------------------------------------------------------------------
REM //スケーリングを行う場合は、下記の行を有効にして、サイズを適切に変更して下さい。
REM //-x,又は,-yの片方だけを指定する事も可能です。その場合、もう一方は自動的に計算されます。
REM //	SET SCALE=-x 540 -y 960

REM //--------------------------------------------------------------------------
REM //クオリティ設定は、以下のいずれかの行を選択して下さい。
REM //上から順に、ハイクォリティ，ミドルクォリティ，ロークォリティです。
REM //尚、ffmpeg2theora.exeのオプションはあまり詳細に見ていないので、他にもクォリティに影響するオプションが有るかも知れません。
REM //	SET QUALITY=-v 10
	SET QUALITY=
REM //	SET QUALITY=-v 0

REM //--------------------------------------------------------------------------
REM //カレントフォルダ以下に有る、*.aviファイルを、全て変換する。
FOR /F "usebackq" %%i IN (`DIR /B /S *.avi`) DO (
  %FFMPEG2THEORA% %SCALE% ^
                  %QUALITY% ^
                  "%%i"
  IF ERRORLEVEL 1 GOTO L_ERR
)

REM //--------------------------------------------------------------------------
ECHO 完了しました。
	TIMEOUT /T 3 /NOBREAK
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
ECHO ###エラーが発生しました。
	PAUSE
EXIT /B 1
