@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0

REM PrdDefNo.hとPrdDefNo.cが既に有れば、確実に削除しておきます。
IF EXIST PrdDefNo.h DEL PrdDefNo.h
IF EXIST PrdDefNo.c DEL PrdDefNo.c

REM ■説明
REM 
REM □sort.exe PrdDef.h ^
REM PrdDef.hをソートします。
REM 名前が連続した演出セットに連番を振ると、プログラムで扱い易いからです。
REM 
REM □ | gawk.exe --re-interval -f %BATDIR%MkPrdDefNo.awk ^
REM PrdDef.h(演出セットインデクスの定義)を、インデクステーブルに変換するAwkスクリプトです。
REM 詳細は、MkPrdDefNo.awkのコメントを参照してください。
REM 
REM □  | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w PrdDef.h" ^
REM                      -e "/{{SOURCE/,/}}SOURCE/w PrdDef.c"
REM ヘッダ部とソース部に切り分けて保存します。

sort.exe PrdDef.h ^
 | gawk.exe --re-interval -f %BATDIR%MkPrdDefNo.awk ^
 | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w PrdDefNo.h" ^
                  -e "/{{SOURCE/,/}}SOURCE/w PrdDefNo.c"

REM PrdDefNo.hとPrdDefNo.cの作成途中でエラー中断した場合は、ファイルを削除して、バッチスクリプトをエラー終了します。
IF EXIST PrdDefNo.h ( grep.exe -q "}}HEADER" PrdDefNo.h || DEL PrdDefNo.h )
IF EXIST PrdDefNo.c ( grep.exe -q "}}SOURCE" PrdDefNo.c || DEL PrdDefNo.c )
IF NOT EXIST PrdDefNo.h EXIT /B 1
IF NOT EXIST PrdDefNo.c EXIT /B 1
