@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0

REM DirSeqNo.hとDirSeqNo.cが既に有れば、確実に削除しておきます。
IF EXIST DirSeqNo.h DEL DirSeqNo.h
IF EXIST DirSeqNo.c DEL DirSeqNo.c

REM ■説明
REM 
REM □sort.exe DirSeq.h ^
REM DirSeq.hをソートします。
REM 名前が連続した演出セットに連番を振ると、プログラムで扱い易いからです。
REM 
REM □ | gawk.exe --re-interval -f %BATDIR%MkDirSeqNo.awk ^
REM DirSeq.h(演出セットインデクスの定義)を、インデクステーブルに変換するAwkスクリプトです。
REM 詳細は、MkDirSeqNo.awkのコメントを参照してください。
REM 
REM □  | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w DirSeq.h" ^
REM                      -e "/{{SOURCE/,/}}SOURCE/w DirSeq.c"
REM ヘッダ部とソース部に切り分けて保存します。

sort.exe DirSeq.h ^
 | gawk.exe --re-interval -f %BATDIR%MkDirSeqNo.awk ^
 | onigsed.exe -n -e "/{{HEADER/,/}}HEADER/w DirSeqNo.h" ^
                  -e "/{{SOURCE/,/}}SOURCE/w DirSeqNo.c"

REM DirSeqNo.hとDirSeqNo.cの作成途中でエラー中断した場合は、ファイルを削除して、バッチスクリプトをエラー終了します。
IF EXIST DirSeqNo.h ( grep.exe -q "}}HEADER" DirSeqNo.h || DEL DirSeqNo.h )
IF EXIST DirSeqNo.c ( grep.exe -q "}}SOURCE" DirSeqNo.c || DEL DirSeqNo.c )
IF NOT EXIST DirSeqNo.h EXIT /B 1
IF NOT EXIST DirSeqNo.c EXIT /B 1
