@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Sun May 31 14:08:56 JST 2015 Naoyuki Sawa
REM // - 1st リリース。
REM // * Mon Dec 21 21:46:29 JST 2015 Naoyuki Sawa
REM // - エラーが発生した時に、不完全な最終出力ファイルを確実に削除するようにしました。
REM // * Sun Jan 03 21:17:56 JST 2016 Naoyuki Sawa
REM // - dEvtTmrC.exeの'-p'オプションを廃止した事に伴い、当バッチファイルも変更しました。
REM //   詳細は、/clip/tool/dEvtTmrC/winapp.h の同日のコメントを参照して下さい。
REM // * Sat Jan 23 21:37:38 JST 2016 Naoyuki Sawa
REM // - パイプライン実行に、pipefail.exeを使用するように変更しました。
REM //   処理内容には、変更は有りません。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkEvtTmr.bat イベントタイマスクリプト [[イベントタイマスクリプト] ...]
REM //│(イベントタイマスクリプトの書式は、dEvtTmrC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、イベントタイマスクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dEvtTmrC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「イベントタイマコンパイラ」を実行します。
REM //環境変数'EVTTMR_BIN'が定義されていなければ、テキスト形式で出力します。
IF "%EVTTMR_BIN%" EQU "" (
  dEvtTmrC.exe -e                %TMPNAM% > EvtTmr.c
  IF ERRORLEVEL 1 GOTO L_ERR
  REM //EvtTmr.cから、ラベル定義の行を抽出して、EvtTmr.hを作成します。
  onigsed.exe -n -e "/^#define EvtTmrNo_/p" ^
                 -e "/^\(const int TBL_EvtTmrNo\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
                 -e "/^\(const unsigned short TBL_EvtTmr\[[1-9][0-9]*\]\[2\]\)={$/{s//extern \1;/;p}" ^
   < EvtTmr.c > EvtTmr.h
  IF ERRORLEVEL 1 GOTO L_ERR
REM //環境変数'EVTTMR_BIN'が定義されてたら、バイナリ形式で出力します。
) ELSE (
  dEvtTmrC.exe -e -o%EVTTMR_BIN% %TMPNAM% > EvtTmr.h
  IF ERRORLEVEL 1 GOTO L_ERR
)
DEL %TMPNAM%

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST EvtTmr.h DEL EvtTmr.h
IF EXIST EvtTmr.c DEL EvtTmr.c
IF "%EVTTMR_BIN%" NEQ "" IF EXIST "%EVTTMR_BIN%" DEL "%EVTTMR_BIN%"
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
