@REM #// * Wed Feb 11 14:57:22 JST 2015 Naoyuki Sawa
@REM #// - Tcl/Tkのスクリプトを、単体で実行出来る.exeファイルに変換するバッチファイルです。
@REM #//   このバッチファイルを使う前に、
@REM #//   「ActiveTcl 8.6.3.1」(http://www.activestate.com/activetcl)を、'C:\Tcl\bin\'にインストールしておいて下さい。
@REM #//   ActiveTclをバージョンアップした場合は、'SET CLI=～'と'SET GUI=～'の定義を変更してください。
@REM #// - 使用例① Tclスクリプト'Sample1.tcl'を、tclsh.exeが無い環境でも実行出来る.exeファイルに変換する方法:
@REM #//   MakeStarpack.bat Sample1.tcl
@REM #//   使用例② Tcl/Tkスクリプト'Sample2.tcl'を、wish.exeが無い環境でも実行出来る.exeファイルに変換する方法:
@REM #//   MakeStarpack.bat Sample2.tcl GUI
@REM #// - デスクトップや、日本語を含むフォルダ内で、当バッチファイルを実行すると、上手く動作しない場合が有るようです。
@REM #//   なるべく浅いフォルダで、日本語を含まないフォルダ内で、実行するようにして下さい。

@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TCLDIR=C:\Tcl\bin\

SET TCL=%TCLDIR%tclsh.exe
SET CLI=%TCLDIR%base-tcl8.6-thread-win32-ix86.exe
SET GUI=%TCLDIR%base-tk8.6-thread-win32-ix86.exe
SET SDX=%BATDIR%sdx-20110317.kit

IF "%1" EQU "" (
  ECHO USAGE: [CALL] %~nx0 FileName.tcl [GUI]
  EXIT /B 1
)

IF /I "%2" EQU "GUI" (
  SET RUNTIME=%GUI%
) ELSE (
  SET RUNTIME=%CLI%
)

(%TCL% %SDX% qwrap %1 -runtime %RUNTIME%) && (MOVE %~dpn1 %~dpn1.exe)
