@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Sun Jan 10 21:20:52 JST 2016 Naoyuki Sawa
REM // - 1st リリース。MkEnmDef.batをベースにしました。
REM // - P/ECEプロジェクトから使用する場合は、環境変数'PIECE'を定義して実行して下さい。<例> env.exe PIECE=1 MkTexDef.bat TexDef.txt SprDef.txt
REM //   Win32プロジェクトから使用する場合は、環境変数'WIN32'を定義して実行して下さい。<例> env.exe WIN32=1 MkTexDef.bat TexDef.txt SprDef.txt
REM // - どちらの環境変数も指定しなければ、両方のプロジェクト用のファイルを全て生成します。これは、テスト用の動作です。
REM // * Thu Jan 14 21:10:13 JST 2016 Naoyuki Sawa
REM // - dTexDefC.exeの列挙定義スクリプトを生成するオプション名を'-m'⇒'-u'に変更した事に伴い、当バッチスクリプトも変更しました。
REM // * Sat Jan 23 21:37:38 JST 2016 Naoyuki Sawa
REM // - パイプライン実行に、pipefail.exeを使用するように変更しました。
REM //   処理内容には、変更は有りません。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkTexDef.bat テクスチャ定義スクリプト [[テクスチャ定義スクリプト] ...]
REM //│(テクスチャ定義スクリプトの書式は、dTexDefC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、テクスチャ定義スクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dTexDefC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「テクスチャ定義コンパイラ」を実行します。
REM //環境変数'PIECE'も'WIN32'も定義されていない場合は、P/ECE用のテクスチャ定義ヘッダとスプライト定義ヘッダ,及び,汎用の列挙定義スクリプトとレジストリスクリプトを全て生成します。
IF "%PIECE%%WIN32%" EQU "" (
  dTexDefC.exe -e -ttexture.h -psprite.h -uEnmTexDef.tmp -rRegTexDef.tmp %TMPNAM%
  IF ERRORLEVEL 1 GOTO L_ERR
  DEL %TMPNAM%
  GOTO L_NEXT
)
REM //環境変数'PIECE'が定義されている場合は、P/ECE用のテクスチャ定義ヘッダとスプライト定義ヘッダを生成し、汎用の列挙定義スクリプトとレジストリスクリプトを生成しません。
IF "%WIN32%" EQU "" (
  dTexDefC.exe -e -ttexture.h -psprite.h %TMPNAM%
  IF ERRORLEVEL 1 GOTO L_ERR
  DEL %TMPNAM%
  GOTO L_NEXT
)
REM //環境変数'WIN32'が定義されている場合は、汎用の列挙定義スクリプトとレジストリスクリプトを生成し、P/ECE用のテクスチャ定義ヘッダとスプライト定義ヘッダを生成しません。
IF "%PIECE%" EQU "" (
  dTexDefC.exe -e -uEnmTexDef.tmp -rRegTexDef.tmp %TMPNAM%
  IF ERRORLEVEL 1 GOTO L_ERR
  DEL %TMPNAM%
  GOTO L_NEXT
)
REM //環境変数'PIECE'と'WIN32'の両方が定義されていた場合は、エラーとします。
ECHO ###環境変数'PIECE'と'WIN32'の両方が定義されています。
GOTO L_ERR
REM //上で処理が成功した場合のジャンプ位置
:L_NEXT

REM //--------------------------------------------------------------------------
REM //□列挙定義スクリプトが生成されていたら、タブ文字を追加して列幅を揃えます。
IF EXIST EnmTexDef.tmp (
  TabAlign.exe EnmTexDef.tmp > EnmTexDef.txt
  IF ERRORLEVEL 1 GOTO L_ERR
  DEL EnmTexDef.tmp
)

REM //--------------------------------------------------------------------------
REM //□レジストリスクリプトが生成されていたら、タブ文字を追加して列幅を揃えます。
IF EXIST RegTexDef.tmp (
  TabAlign.exe RegTexDef.tmp > RegTexDef.txt
  IF ERRORLEVEL 1 GOTO L_ERR
  DEL RegTexDef.tmp
)

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST   texture.h   DEL   texture.h
IF EXIST    sprite.h   DEL    sprite.h
IF EXIST EnmTexDef.txt DEL EnmTexDef.txt
IF EXIST RegTexDef.txt DEL RegTexDef.txt
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
