%{
/*{{定型コード:y.tab.y(宣言部,%{〜%}内)======================================*/
#ifdef  PIECE
#include "app.h"
#else //PIECE
#include "winapp.h"
#pragma warning(default: 4131)	//{{2016/03/01追加:clipstd.hにてC4131の警告レベルを引き上げましたが、Bison/Flexの生成コードには旧スタイルの宣言が使われているので、Bison/Flexの生成コードのみ警告レベルを元に戻しました。}}
#endif//PIECE
/* パーサースタックの初期値を定義します。
 * sizeof(YYSTYPE)*YYINITDEPTH) がスタック上に確保されます。
 * デフォルトでは200と定義されており、P/ECEには大きすぎます。
 * P/ECEに適切な、小さなサイズ(16)に、再定義しました。
 * パーサースタックが不足した場合は、自動的に拡張されるので、問題ありません。
 */
#define YYINITDEPTH 16
///* エラー報告関数を定義します。 */	→{{2015/03/06:'-e'オプション対応のためにwinapp.cへ移動しました。}}
//void yyerror(const char* fmt, ...) {
//  fprintf(stderr, "### error at line %d : ", yylineno);
//  { va_list ap; va_start(ap, fmt); vfprintf(stderr, fmt, ap); va_end(ap); }
//  fputc('\n', stderr); }
/*}}定型コード:y.tab.y(宣言部,%{〜%}内)======================================*/
%}

%union {
	int		v_num;
	double		v_dbl;
	char*		v_str;
	ST_ExprList*	v_exprList;
	ST_RgnMap*	v_rgnMap;
	ST_RgnMapBody*	v_rgnMapBody;
	ST_RgnDef*	v_rgnDef;
	ST_RgnDefBody*	v_rgnDefBody;
	ST_RgnFig*	v_rgnFig;
}

%token	<v_num>		T_NUM
%token	<v_dbl>		T_DBL
%token	<v_str>		T_LAB
%token	<v_str>		T_STR
%token			T_EOL
%token			T_END
%token			T_RECT
%token			T_OVAL
%token			T_POLY

%type	<v_num>		int_arg
%type	<v_num>		expr
%type	<v_dbl>		edbl
%type	<v_str>		estr
%type	<v_str>		labelRow
%type	<v_exprList>	exprList
%type	<v_rgnMap>	rgnMap
%type	<v_rgnMapBody>	rgnMapBody
%type	<v_rgnDef>	rgnDef
%type	<v_rgnDefBody>	rgnDefBody
%type	<v_rgnFig>	rgnFig
%type	<v_num>		rgnFigType

%left			'|'
%left			'^'
%left			'&'
%left			T_SHL T_SHR
%left			'+' '-'
%left			'*' '/' '%'
%nonassoc		'~' T_UPL T_UMI T_CAST_INT T_CAST_DBL

%%

all
		: pre_blank
		| all rgnMap					{ addRgnMap($2); yyerrok; }	//error記号の位置について『http://www.pwv.co.jp/~take/TakeWiki/index.php?Cコンパイラ設計(yacc・lexの応用)/第4章　エラー・リカバリ#dbd8d417』の【optional sequence】を参考にした。
		| all error									//全てのシンタクスエラーを報告するために継続する。
		;
pre_blank
		: /* empty */
		| pre_blank T_EOL
		;
eols
		:      T_EOL
		| eols T_EOL
		;
end
		: T_END eols
		;
int_arg
		: expr						/* use default action */
		| edbl						{ $$ =  cast_dbl_to_int($1); }
		;
expr
		: T_NUM						/* use default action */
		| '(' expr ')'					{ $$ =  $2; }
		| T_CAST_INT expr				{ $$ =  $2; }
		| T_CAST_INT edbl				{ $$ =  $2; }
		| '+' expr %prec T_UPL				{ $$ =  $2; }
		| '-' expr %prec T_UMI				{ $$ = -$2; }
		| '~' expr					{ $$ = ~$2; }
		| expr '+' expr					{ $$ = $1 + $3; }
		| expr '-' expr					{ $$ = $1 - $3; }
		| expr '*' expr					{ $$ = $1 * $3; }
		| expr '/' expr					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
		| expr '%' expr					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 % $3; }
		| expr '&' expr					{ $$ = $1 & $3; }
		| expr '^' expr					{ $$ = $1 ^ $3; }
		| expr '|' expr					{ $$ = $1 | $3; }
		| expr T_SHL expr				{ if((unsigned)$3 >= 32) { yyerror("shift count >= 32"); yynerrs++; YYERROR; } $$ = $1 << $3; }
		| expr T_SHR expr				{ if((unsigned)$3 >= 32) { yyerror("shift count >= 32"); yynerrs++; YYERROR; } $$ = $1 >> $3; }
		;
edbl
		: T_DBL
		| '(' edbl ')'					{ $$ =  $2; }
		| T_CAST_DBL expr				{ $$ =  $2; }
		| T_CAST_DBL edbl				{ $$ =  $2; }
		| '+' edbl %prec T_UPL				{ $$ =  $2; }
		| '-' edbl %prec T_UMI				{ $$ = -$2; }
		| edbl '+' edbl					{ $$ = $1 + $3; }
		| edbl '+' expr					{ $$ = $1 + $3; }
		| expr '+' edbl					{ $$ = $1 + $3; }
		| edbl '-' edbl					{ $$ = $1 - $3; }
		| edbl '-' expr					{ $$ = $1 - $3; }
		| expr '-' edbl					{ $$ = $1 - $3; }
		| edbl '*' edbl					{ $$ = $1 * $3; }
		| edbl '*' expr					{ $$ = $1 * $3; }
		| expr '*' edbl					{ $$ = $1 * $3; }
		| edbl '/' edbl					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
		| edbl '/' expr					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
		| expr '/' edbl					{ if(!$3) { yyerror("division or modulo by zero"); yynerrs++; YYERROR; } $$ = $1 / $3; }
		;
estr
		: T_STR
		| '(' estr ')'					{ $$ = $2; }
		| estr '+' estr					{ $$ = strconcat($1, $3, NULL); }
		;
		/*--------------------------------------------*/
labelRow
		: T_LAB      eols				/* use default action */
		| T_LAB estr eols				/* use default action */	//estrは参照しません。estrを'Useless nonterminals'エラーにしないためのダミーです。
		;
		/*--------------------------------------------*/
exprList
		:              int_arg				{ if(!($$ = ExprList_New(         $1))) { YYERROR; } }			//現在の所エラーが発生する事は無い。
		| exprList ',' int_arg				{ if(!($$ = ExprList_AddValue($1, $3))) { YYERROR; } }			//現在の所エラーが発生する事は無い。
		;
		/*--------------------------------------------*/
rgnMap
		: labelRow rgnMapBody end			{ if(!($$ = RgnMap_New($1, $2))) { YYERROR; } }				//現在の所エラーが発生する事は無い。
		;
rgnMapBody
		:            rgnDef				{ if(!($$ = RgnMapBody_New(          $1))) { YYERROR; } }		//現在の所エラーが発生する事は無い。
		| rgnMapBody rgnDef				{ if(!($$ = RgnMapBody_AddRgnDef($1, $2))) { YYERROR; } }		//このRgnMap内でRgnDefのラベルが重複していたらエラーとする。
		;
		/*--------------------------------------------*/
rgnDef
		: T_LAB    rgnFig				{ if(!($$ = RgnDef_New($1, RgnDefBody_New($2)))) { YYERROR; } }		//現在の所エラーが発生する事は無い。	一つだけのrgnFigから成るrgnDefの簡略記法です。
		| labelRow rgnDefBody end			{ if(!($$ = RgnDef_New($1,                $2 ))) { YYERROR; } }		//現在の所エラーが発生する事は無い。	一つ以上のrgnFigから成るrgnDefの一般記法です。
		;
rgnDefBody
		:            rgnFig				{ if(!($$ = RgnDefBody_New(          $1))) { YYERROR; } }		//現在の所エラーが発生する事は無い。
		| rgnDefBody rgnFig				{ if(!($$ = RgnDefBody_AddRgnFig($1, $2))) { YYERROR; } }		//現在の所エラーが発生する事は無い。
		;
		/*--------------------------------------------*/
rgnFig
		: exprList rgnFigType eols			{ if(!($$ = RgnFig_New($2, $1))) { YYERROR; } }				//exprListの内容とrgnFigTypeが合っていなければエラーとする。
		;
rgnFigType
		: /* empty */					{ $$ = RgnFigType_rect; }						//RgnFigの種類を省略すると'rect'と見なす事にした。別の案として省略時は一番汎用的な'poly'と見なす事も考えたのですが、実際の所'poly'よりも'rect'を定義する事の方が遥かに多いと思うので、'rect'を書く手間を省ける方が実用的だと思ってこうする事にしました。
		| T_RECT					{ $$ = RgnFigType_rect; }
		| T_OVAL					{ $$ = RgnFigType_oval; }
		| T_POLY					{ $$ = RgnFigType_poly; }
		;

%%
