@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Mon Mar 23 21:35:39 JST 2015 Naoyuki Sawa
REM // - 1st リリース。
REM // * Thu Mar 26 21:28:16 JST 2015 Naoyuki Sawa
REM // - dRegTblC.exeの出力データ構造を変更した事に伴い、当バッチスクリプトも変更しました。
REM //   当バッチスクリプトの変更点は、'unsigned short'⇒'unsigned char'に変更した事だけです。
REM // * Mon Dec 21 21:46:29 JST 2015 Naoyuki Sawa
REM // - エラーが発生した時に、不完全な最終出力ファイルを確実に削除するようにしました。
REM // * Sun Jan 03 21:17:56 JST 2016 Naoyuki Sawa
REM // - dRegTblC.exeの'-p'オプションを廃止した事に伴い、当バッチファイルも変更しました。
REM //   詳細は、/clip/tool/dRegTblC/winapp.h の同日のコメントを参照して下さい。
REM // * Sat Jan 23 21:37:38 JST 2016 Naoyuki Sawa
REM // - パイプライン実行に、pipefail.exeを使用するように変更しました。
REM //   処理内容には、変更は有りません。
REM // * Sun Mar 26 22:13:56 JST 2017 Naoyuki Sawa
REM // - 環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM // * Mon Mar 27 22:39:32 JST 2017 Naoyuki Sawa
REM // - 環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
REM //   C#プロジェクトでC言語形式のヘッダファイルが必要かどうかは各アプリケーション次第なので、この処理は当バッチスクリプトでなく各アプリケーションのバッチスクリプトに書こうかとも思ったのですが、
REM //   実際の所、他のツールのスクリプトへの入力としてC言語形式のヘッダファイルは大抵必要なので、毎回、各アプリケーションのバッチスクリプトに書く手間を省くために、当バッチスクリプトに含めました。
REM //   不要ならば、各アプリケーションのバッチスクリプトで、当バッチスクリプトを呼び出した後、当バッチスクリプトが生成したC言語形式のヘッダファイルを削除して下さい。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkRegTbl.bat レジストリテーブルスクリプト [[レジストリテーブルスクリプト] ...]
REM //│(レジストリテーブルスクリプトの書式は、dRegTblC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、レジストリテーブルスクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dRegTblC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「レジストリテーブルコンパイラ」を実行します。
REM //{{2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM //REM //環境変数'REGTBL_BIN'が定義されていなければ、テキスト形式で出力します。
REM //IF "%REGTBL_BIN%" EQU "" (
REM //  dRegTblC.exe -e                %TMPNAM% > RegTbl.c
REM //  IF ERRORLEVEL 1 GOTO L_ERR
REM //  REM //RegTbl.cから、シンボル定義の行を抽出して、RegTbl.hを作成します。
REM //  onigsed.exe -n -e "/^#define RegKey_/p" ^
REM //                 -e "/^\(const unsigned char TBL_RegTbl\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
REM //   < RegTbl.c > RegTbl.h
REM //  IF ERRORLEVEL 1 GOTO L_ERR
REM //REM //環境変数'REGTBL_BIN'が定義されてたら、バイナリ形式で出力します。
REM //) ELSE (
REM //  dRegTblC.exe -e -o%REGTBL_BIN% %TMPNAM% > RegTbl.h
REM //  IF ERRORLEVEL 1 GOTO L_ERR
REM //)
REM //↓2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM //□環境変数'CSHARP'が定義されていなければ、出力ソースをC言語形式とする。
IF "%CSHARP%" EQU "" (
  REM //環境変数'REGTBL_BIN'が定義されていなければ、テキスト形式で出力します。
  IF "%REGTBL_BIN%" EQU "" (
    dRegTblC.exe -e                     %TMPNAM% > RegTbl.c
    IF ERRORLEVEL 1 GOTO L_ERR
    REM //RegTbl.cから、シンボル定義の行を抽出して、RegTbl.hを作成します。
    onigsed.exe -n -e "/^#define RegKey_/p" ^
                   -e "/^\(const unsigned char TBL_RegTbl\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
     < RegTbl.c > RegTbl.h
    IF ERRORLEVEL 1 GOTO L_ERR
  REM //環境変数'REGTBL_BIN'が定義されてたら、バイナリ形式で出力します。
  ) ELSE (
    dRegTblC.exe -e      -o%REGTBL_BIN% %TMPNAM% > RegTbl.h
    IF ERRORLEVEL 1 GOTO L_ERR
  )
REM //□環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とする。
) ELSE (
  REM //環境変数'REGTBL_BIN'が定義されていなければ、テキスト形式で出力します。
  IF "%REGTBL_BIN%" EQU "" (
    dRegTblC.exe -e -xcs                %TMPNAM% > RegTbl.cs
    IF ERRORLEVEL 1 GOTO L_ERR
    REM //C#形式ではソース一つなので、ラベル定義の行を抽出する処理は不要です。
  REM //環境変数'REGTBL_BIN'が定義されてたら、バイナリ形式で出力します。
  ) ELSE (
    dRegTblC.exe -e -xcs -o%REGTBL_BIN% %TMPNAM% > RegTbl.cs
    IF ERRORLEVEL 1 GOTO L_ERR
  )
  REM //{{2017/03/27追加:環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
  CALL ConvertCsToH.bat RegTbl.cs > RegTbl.h
  IF ERRORLEVEL 1 GOTO L_ERR
  REM //}}2017/03/27追加:環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
)
REM //}}2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
DEL %TMPNAM%

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST RegTbl.h  DEL RegTbl.h
IF EXIST RegTbl.c  DEL RegTbl.c
IF EXIST RegTbl.cs DEL RegTbl.cs
IF "%REGTBL_BIN%" NEQ "" IF EXIST "%REGTBL_BIN%" DEL "%REGTBL_BIN%"
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
