@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Thu Feb 23 21:53:55 JST 2017 Naoyuki Sawa
REM // - 1st リリース。MkTexDef.batをベースにしました。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkVslDef.bat ビデオスロットゲーム定義スクリプト [[ビデオスロットゲーム定義スクリプト] ...]
REM //│(ビデオスロットゲーム定義スクリプトの書式は、dVslDefC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、ビデオスロットゲーム定義スクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dVslDefC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「ビデオスロットゲーム定義コンパイラ」を実行します。
dVslDefC.exe -e -uEnmVslDef.tmp -rRegVslDef.tmp %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR
DEL %TMPNAM%

REM //--------------------------------------------------------------------------
REM //□列挙定義スクリプトに、タブ文字を追加して列幅を揃えます。
TabAlign.exe EnmVslDef.tmp > EnmVslDef.txt
IF ERRORLEVEL 1 GOTO L_ERR
DEL EnmVslDef.tmp

REM //--------------------------------------------------------------------------
REM //□レジストリスクリプトに、タブ文字を追加して列幅を揃えます。
TabAlign.exe RegVslDef.tmp > RegVslDef.txt
IF ERRORLEVEL 1 GOTO L_ERR
DEL RegVslDef.tmp

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST EnmVslDef.txt DEL EnmVslDef.txt
IF EXIST RegVslDef.txt DEL RegVslDef.txt
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
