@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Tue Sep 15 21:59:16 JST 2015 Naoyuki Sawa
REM // - 1st リリース。MkSndDef.batをベースにしました。
REM // * Mon Dec 21 21:46:29 JST 2015 Naoyuki Sawa
REM // - エラーが発生した時に、不完全な最終出力ファイルを確実に削除するようにしました。
REM // * Sun Jan 03 21:17:56 JST 2016 Naoyuki Sawa
REM // - dTapSeqC.exeの'-p'オプションを廃止した事に伴い、当バッチファイルも変更しました。
REM //   詳細は、/clip/tool/dTapSeqC/winapp.h の同日のコメントを参照して下さい。
REM // * Sat Jan 23 21:37:38 JST 2016 Naoyuki Sawa
REM // - パイプライン実行に、pipefail.exeを使用するように変更しました。
REM //   処理内容には、変更は有りません。
REM // * Sun Mar 26 22:13:56 JST 2017 Naoyuki Sawa
REM // - 環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM // * Mon Mar 27 22:39:32 JST 2017 Naoyuki Sawa
REM // - 環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
REM //   C#プロジェクトでC言語形式のヘッダファイルが必要かどうかは各アプリケーション次第なので、この処理は当バッチスクリプトでなく各アプリケーションのバッチスクリプトに書こうかとも思ったのですが、
REM //   実際の所、他のツールのスクリプトへの入力としてC言語形式のヘッダファイルは大抵必要なので、毎回、各アプリケーションのバッチスクリプトに書く手間を省くために、当バッチスクリプトに含めました。
REM //   不要ならば、各アプリケーションのバッチスクリプトで、当バッチスクリプトを呼び出した後、当バッチスクリプトが生成したC言語形式のヘッダファイルを削除して下さい。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkTapDef.bat TAPシーケンサスクリプト [[TAPシーケンサスクリプト] ...]
REM //│(TAPシーケンサスクリプトの書式は、dTapSeqC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、TAPシーケンサスクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dTapSeqC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「TAPシーケンサコンパイラ」を実行します。
REM //{{2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM //REM //環境変数'TAPDEF_BIN'が定義されていなければ、テキスト形式で出力します。
REM //IF "%TAPDEF_BIN%" EQU "" (
REM //  dTapSeqC.exe -e                %TMPNAM% > TapDef.c
REM //  IF ERRORLEVEL 1 GOTO L_ERR
REM //  REM //TapDef.cから、ラベル定義の行を抽出して、TapDef.hを作成します。
REM //  onigsed.exe -n -e "/^#define TapSeqNo_/p" ^
REM //                 -e "/^\(const int TBL_TapSeqNo\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
REM //                 -e "/^\(const unsigned char TBL_TapSeq\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
REM //   < TapDef.c > TapDef.h
REM //  IF ERRORLEVEL 1 GOTO L_ERR
REM //REM //環境変数'TAPDEF_BIN'が定義されてたら、バイナリ形式で出力します。
REM //) ELSE (
REM //  dTapSeqC.exe -e -o%TAPDEF_BIN% %TMPNAM% > TapDef.h
REM //  IF ERRORLEVEL 1 GOTO L_ERR
REM //)
REM //↓2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM //□環境変数'CSHARP'が定義されていなければ、出力ソースをC言語形式とする。
IF "%CSHARP%" EQU "" (
  REM //環境変数'TAPDEF_BIN'が定義されていなければ、テキスト形式で出力します。
  IF "%TAPDEF_BIN%" EQU "" (
    dTapSeqC.exe -e                     %TMPNAM% > TapDef.c
    IF ERRORLEVEL 1 GOTO L_ERR
    REM //TapDef.cから、ラベル定義の行を抽出して、TapDef.hを作成します。
    onigsed.exe -n -e "/^#define TapSeqNo_/p" ^
                   -e "/^\(const int TBL_TapSeqNo\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
                   -e "/^\(const unsigned char TBL_TapSeq\[[1-9][0-9]*\]\)={$/{s//extern \1;/;p}" ^
     < TapDef.c > TapDef.h
    IF ERRORLEVEL 1 GOTO L_ERR
  REM //環境変数'TAPDEF_BIN'が定義されてたら、バイナリ形式で出力します。
  ) ELSE (
    dTapSeqC.exe -e      -o%TAPDEF_BIN% %TMPNAM% > TapDef.h
    IF ERRORLEVEL 1 GOTO L_ERR
  )
REM //□環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とする。
) ELSE (
  REM //環境変数'TAPDEF_BIN'が定義されていなければ、テキスト形式で出力します。
  IF "%TAPDEF_BIN%" EQU "" (
    dTapSeqC.exe -e -xcs                %TMPNAM% > TapDef.cs
    IF ERRORLEVEL 1 GOTO L_ERR
    REM //C#形式ではソース一つなので、ラベル定義の行を抽出する処理は不要です。
  REM //環境変数'TAPDEF_BIN'が定義されてたら、バイナリ形式で出力します。
  ) ELSE (
    dTapSeqC.exe -e -xcs -o%TAPDEF_BIN% %TMPNAM% > TapDef.cs
    IF ERRORLEVEL 1 GOTO L_ERR
  )
  REM //{{2017/03/27追加:環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
  CALL ConvertCsToH.bat TapDef.cs > TapDef.h
  IF ERRORLEVEL 1 GOTO L_ERR
  REM //}}2017/03/27追加:環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
)
REM //}}2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
DEL %TMPNAM%

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST TapDef.h DEL TapDef.h
IF EXIST TapDef.c DEL TapDef.c
IF "%TAPDEF_BIN%" NEQ "" IF EXIST "%TAPDEF_BIN%" DEL "%TAPDEF_BIN%"
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
