@ECHO OFF
SETLOCAL
SET BATDIR=%~dp0
SET TMPNAM=%~n0.tmp

REM //--------------------------------------------------------------------------
REM // * Fri Jan 01 21:14:34 JST 2016 Naoyuki Sawa
REM // - 1st リリース。MkPrpTbl.batをベースにしました。
REM // * Sat Jan 23 21:37:38 JST 2016 Naoyuki Sawa
REM // - パイプライン実行に、pipefail.exeを使用するように変更しました。
REM //   処理内容には、変更は有りません。
REM // * Sun Mar 26 22:13:56 JST 2017 Naoyuki Sawa
REM // - 環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM // * Mon Mar 27 22:39:32 JST 2017 Naoyuki Sawa
REM // - 環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
REM //   C#プロジェクトでC言語形式のヘッダファイルが必要かどうかは各アプリケーション次第なので、この処理は当バッチスクリプトでなく各アプリケーションのバッチスクリプトに書こうかとも思ったのですが、
REM //   実際の所、他のツールのスクリプトへの入力としてC言語形式のヘッダファイルは大抵必要なので、毎回、各アプリケーションのバッチスクリプトに書く手間を省くために、当バッチスクリプトに含めました。
REM //   不要ならば、各アプリケーションのバッチスクリプトで、当バッチスクリプトを呼び出した後、当バッチスクリプトが生成したC言語形式のヘッダファイルを削除して下さい。

REM //--------------------------------------------------------------------------
REM //■使い方
REM //│CALL MkEnmDef.bat 列挙定義スクリプト [[列挙定義スクリプト] ...]
REM //│(列挙定義スクリプトの書式は、dEnmDefC.exeの説明を参照してください。)

REM //--------------------------------------------------------------------------
REM //□'cpp.exe'を通しているので、列挙定義スクリプト内でCプリプロセッサの疑似命令も使えます。
REM //│'cpp.exe'に'-P'を指定していないので'# 行番号 "ファイル名"'が生成されますが、dEnmDefC.exeがコメントとして無視するので問題ありません。
REM //│'cpp.exe'に'-P'を指定してもしなくても同じ結果になるはずです。
pipefail.exe -q dpesc5c.exe %* ^
             ^| cpp.exe ^
 > %TMPNAM%
IF ERRORLEVEL 1 GOTO L_ERR

REM //--------------------------------------------------------------------------
REM //□「列挙定義コンパイラ」を実行します。
REM // - ヘッダファイルにタブ文字を追加して列幅を揃えます。
REM //{{2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM //pipefail.exe -q dEnmDefC.exe -e -rRegEnmDef.tmp %TMPNAM% ^
REM //             ^| TabAlign.exe ^
REM // > EnmDef.h
REM //IF ERRORLEVEL 1 GOTO L_ERR
REM //↓2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
REM //□環境変数'CSHARP'が定義されていなければ、出力ソースをC言語形式とする。
IF "%CSHARP%" EQU "" (
  pipefail.exe -q dEnmDefC.exe -e      -rRegEnmDef.tmp %TMPNAM% ^
               ^| TabAlign.exe ^
   > EnmDef.h
  IF ERRORLEVEL 1 GOTO L_ERR
REM //□環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とする。
) ELSE (
  pipefail.exe -q dEnmDefC.exe -e -xcs -rRegEnmDef.tmp %TMPNAM% ^
               ^| TabAlign.exe ^
   > EnmDef.cs
  IF ERRORLEVEL 1 GOTO L_ERR
  REM //{{2017/03/27追加:環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
  CALL ConvertCsToH.bat EnmDef.cs > EnmDef.h
  IF ERRORLEVEL 1 GOTO L_ERR
  REM //}}2017/03/27追加:環境変数'CSHARP'が定義された場合に、ConvertCsToH.batを使ってC#形式の出力ソースからC言語形式のヘッダファイルを生成する処理も、当バッチスクリプトに含めました。
)
REM //}}2017/03/26変更:環境変数'CSHARP'が定義されていたら、出力ソースをC#形式とするようにしました。
DEL %TMPNAM%

REM //--------------------------------------------------------------------------
REM //□レジストリスクリプトにタブ文字を追加して列幅を揃えます。
TabAlign.exe RegEnmDef.tmp > RegEnmDef.txt
IF ERRORLEVEL 1 GOTO L_ERR
DEL RegEnmDef.tmp

REM //--------------------------------------------------------------------------
REM //ECHO 完了しました。
REM //PAUSE
EXIT /B

REM //--------------------------------------------------------------------------
:L_ERR
REM //□不完全な最終出力ファイルを確実に削除します。
IF EXIST    EnmDef.h   DEL    EnmDef.h
IF EXIST    EnmDef.cs  DEL    EnmDef.cs
IF EXIST RegEnmDef.txt DEL RegEnmDef.txt
ECHO ###エラーが発生しました。
REM //PAUSE
EXIT /B 1
